Groovy (programming language)
![]() | |
Paradigm | Object-oriented, imperative, scripting |
---|---|
Designed by | James Strachan |
Developer |
Guillaume Laforge (PMC Chair) Jochen Theodorou (Tech Lead) Paul King Cedric Champeau |
First appeared | 2003 |
Stable release |
2.4.7
/ June 7, 2016 |
Typing discipline | Dynamic, Static, Strong, Duck |
Platform | Java SE |
License | Apache License v2.0 |
Filename extensions | .groovy |
Website |
groovy-lang |
Influenced by | |
Java, Python, Ruby, Perl, Smalltalk, Objective-C | |
Influenced | |
Kotlin |
Apache Groovy is an object-oriented programming language for the Java platform. It is a dynamic language with features similar to those of Python, Ruby, Perl, and Smalltalk. It can be used as a scripting language for the Java Platform, is dynamically compiled to Java Virtual Machine (JVM) bytecode, and interoperates with other Java code and libraries. Groovy uses a Java-like curly-bracket syntax. Most Java code is also syntactically valid Groovy, although semantics may be different.
Groovy 1.0 was released on January 2, 2007, and Groovy 2.0 in July, 2012. Since version 2, Groovy can also be compiled statically, offering type inference and performance very close to that of Java.[1][2] Groovy 2.4 was the last major release under Pivotal Software's sponsorship which ended in March 2015.[3] Groovy has since changed its governance structure to a Project Management Committee (PMC) in the Apache Software Foundation.[4]
History
James Strachan first talked about the development of Groovy on his blog in August 2003.[5] Several versions were released between 2004 and 2006. After the Java Community Process (JCP) standardization process began, the version numbering changed and a version called "1.0" was released on January 2, 2007. After various betas and release candidates numbered 1.1, on December 7, 2007, Groovy 1.1 Final was released and immediately rebranded as Groovy 1.5 as a reflection of the many changes made.
In 2007, Groovy won the first prize at JAX 2007 innovation award.[6] In 2008, Grails, a Groovy web framework, won the second prize at JAX 2008 innovation award.[7]
In November 2008, SpringSource acquired the Groovy and Grails company (G2One).[8] In August 2009 VMWare acquired SpringSource.[9]
In July 2009, Strachan wrote on his blog, "I can honestly say if someone had shown me the Programming in Scala book by Martin Odersky, Lex Spoon & Bill Venners back in 2003 I'd probably have never created Groovy."[10] Strachan had left the project silently a year before the Groovy 1.0 release in 2007.
In March 2004, Groovy had been submitted to the JCP as JSR 241[11] and accepted by ballot. After 8 years of inactivity, the Spec Lead changed its status to dormant in April 2012.
On July 2, 2012, Groovy 2.0 was released, which, among other new features, added static compilation and a static type checker to Groovy.
When the Pivotal joint venture was spun-off by EMC and VMware in April 2013, Groovy and Grails formed part of its product portfolio. Pivotal ceased sponsoring Groovy and Grails from April 2015.[3] That same month, Groovy changed its governance structure from a Codehaus repository to a Project Management Committee (PMC) in the Apache Software Foundation via its incubator.[4] Groovy graduated from Apache's incubator and become a top-level project in November 2015.[12]
Features
Most valid Java files are also valid Groovy files. Although the two languages are similar, Groovy code can be more compact, because it does not require all the elements that Java requires.[13] This makes it possible for Java programmers to learn Groovy gradually by starting with familiar Java syntax before acquiring more Groovy idioms.[14]
Groovy features not available in Java include both static and dynamic typing (with the def keyword), operator overloading, native syntax for lists and associative arrays (maps), native support for regular expressions, polymorphic iteration, expressions embedded inside strings, additional helper methods, and the safe navigation operator "?." to check automatically for nulls (for example, "variable?.method()", or "variable?.field").[15]
Since version 2 Groovy also supports modularity (being able to ship only the needed jars according to the project needs, thus reducing the size of groovy's lib), type checking, static compilation, Project Coin syntax enhancements, multicatch blocks and ongoing performance enhancements using JDK7's invoke dynamic instruction.[16]
Groovy provides native support for various markup languages such as XML and HTML, accomplished via an inline DOM syntax. This feature enables the definition and manipulation of many types of heterogeneous data assets with a uniform and concise syntax and programming methodology.
Unlike Java, a Groovy source code file can be executed as an (uncompiled) script if it contains code outside any class definition, if it is a class with a main method, or if it is a Runnable or GroovyTestCase. A Groovy script is fully parsed, compiled, and generated before execution (similar to Perl and Ruby). This occurs under the hood, and the compiled version is not saved as an artifact of the process.[17]
GroovyBeans / Properties
GroovyBeans are Groovy's version of JavaBeans. Groovy implicitly generates getters and setters. In the following code, setColor(String color) and getColor() are implicitly generated; and the last two lines, which appear to access color directly, are actually calling the implicitly generated methods.[18]
class AGroovyBean {
String color
}
def myGroovyBean = new AGroovyBean()
myGroovyBean.setColor('baby blue')
assert myGroovyBean.getColor() == 'baby blue'
myGroovyBean.color = 'pewter'
assert myGroovyBean.color == 'pewter'
Groovy offers simple, consistent syntax for handling lists and maps, reminiscent of Java's array syntax.[19]
def movieList = ['Dersu Uzala', 'Ran', 'Seven Samurai'] //looks like an array, but is a list
assert movieList[2] == 'Seven Samurai'
movieList[3] = 'Casablanca' // adds an element to the list
assert movieList.size() == 4
def monthMap = [ 'January' : 31, 'February' : 28, 'March' : 31 ] //declares a map
assert monthMap['March'] == 31 // accesses an entry
monthMap['April'] = 30 // adds an entry to the map
assert monthMap.size() == 4
Prototype extension
Groovy offers support for prototype extension through ExpandoMetaClass, Extension Modules (only in Groovy 2), Objective-C-like Categories and DelegatingMetaClass.[20]
ExpandoMetaClass offers a domain-specific language (DSL) to express the changes in the class easily, similar to Ruby's open class concept:
Number.metaClass {
sqrt = { Math.sqrt(delegate) }
}
assert 9.sqrt() == 3
assert 4.sqrt() == 2
Groovy's changes in code through prototyping are not visible in Java, since each attribute/method invocation in Groovy goes through the metaclass registry. The changed code can only be accessed from Java by going to the metaclass registry.
Groovy also allows overriding methods as getProperty()
, propertyMissing()
among others, enabling the developer to intercept calls to an object and specify an action for them, in a simplified aspect-oriented way. The following code enables the class java.lang.String
to respond to the hex
property:
enum Color {
BLACK('#000000'), WHITE('#FFFFFF'), RED('#FF0000'), BLUE('#0000FF')
String hex
Color(String hex) {
this.hex = hex
}
}
String.metaClass.getProperty = { String property ->
def stringColor = delegate
if (property == 'hex') {
Color.values().find { it.name().equalsIgnoreCase stringColor }?.hex
}
}
assert "WHITE".hex == "#FFFFFF"
assert "BLUE".hex == "#0000FF"
assert "BLACK".hex == "#000000"
assert "GREEN".hex == null
The Grails framework uses metaprogramming extensively to enable GORM dynamic finders, like User.findByName('Josh')
and others.[21]
Dot and parentheses
Groovy's syntax permits omitting parentheses and dots in some situations. The following groovy code
take(coffee).with(sugar, milk).and(liquor)
can be written as
take coffee with sugar, milk and liquor
enabling the development of domain-specific languages (DSLs) which look like plain English.
Functional programming
Although Groovy is mostly an object-oriented language, it also offers functional features.
Closures
According to Groovy's documentation: "Closures in Groovy work similar to a 'method pointer', enabling code to be written and run in a later point in time".[22] Groovy's closures support free variables, i.e. variables which have not been explicitly passed as a parameter to it, but exist in its declaration context, partial application (which it terms 'currying'[23]), delegation, implicit, typed and untyped parameters.
When working on Collections of a determined type, the closure passed to an operation on the collection can be inferred:
list = [1, 2, 3, 4, 5, 6, 7, 8, 9]
/*
* Non-zero numbers are coerced to true, so when it % 2 == 0 (even), it is false.
* The type of the implicit "it" parameter can be inferred as an Integer by the IDE.
* It could also be written as:
* list.findAll { Integer i -> i % 2 }
* list.findAll { i -> i % 2 }
*/
def odds = list.findAll { it % 2 }
assert odds == [1, 3, 5, 7, 9]
A group of expressions can be written in a closure block without reference to an implementation and the responding object can be assigned at a later point using delegation:
// This block of code contains expressions without reference to an implementation
def operations = {
declare 5
sum 4
divide 3
print
}
/*
* This class will handle the operations that can be used in the closure above. We could declare
* another class having the same methods, but using, for example, webservice operations in the
* calculations.
*/
class Expression {
BigDecimal value
/*
* Though an Integer is passed as a parameter, it is coerced into a BigDecimal, as we defined.
* If the class had a 'declare(Integer value)' method, it would be used instead.
*/
def declare(BigDecimal value) {
this.value = value
}
def sum(BigDecimal valueToAdd) {
this.value += valueToAdd
}
def divide(BigDecimal divisor) {
this.value /= divisor
}
def propertyMissing(String property) {
if (property == "print") println value
}
}
// Here we define who is going to respond the expressions in the block
operations.delegate = new Expression()
operations()
Curry
Usually called partial application,[23] this Groovy feature allows closures' parameters to be set to a default parameter in any of their arguments, creating a new closure with the bound value. If you supply one argument to the curry() method you will fix the first argument. If you supply N arguments you will fix arguments 1..N.
def joinTwoWordsWithSymbol = { symbol, first, second -> first + symbol + second }
assert joinTwoWordsWithSymbol('#', 'Hello', 'World') == 'Hello#World'
def concatWords = joinTwoWordsWithSymbol.curry(' ')
assert concatWords('Hello', 'World') == 'Hello World'
def prependHello = concatWords.curry('Hello')
// def prependHello = joinTwoWordsWithSymbol.curry(' ', 'Hello')
assert prependHello('World') == 'Hello World'
Curry can also be used in the reversed direction (fixing arguments N to N-1) using rcurry.
def power = { BigDecimal value, BigDecimal power ->
value ** power
}
def square = power.rcurry(2)
def cube = power.rcurry(3)
assert power(2, 2) == 4
assert square(4) == 16
assert cube(3) == 27
Groovy also supports lazy evaluation,[24][25] reduce/fold,[26] infinite structures and immutability,[27] among others.[28]
XML and JSON processing
On XML and JSON processing Groovy employs the Builder pattern, making the production of the data structure less verbose. For example, the following XML:
<languages>
<language year="1995">
<name>java</name>
<paradigm>Object oriented</paradigm>
<typing>Static</typing>
</language>
<language year="1995">
<name>ruby</name>
<paradigm>Object oriented, Functional</paradigm>
<typing>Dynamic, duck typing</typing>
</language>
<language year="2003">
<name>groovy</name>
<paradigm>Object oriented, Functional</paradigm>
<typing>Dynamic, Static, Duck typing</typing>
</language>
</languages>
Can be generated through the following Groovy code:
def writer = new StringWriter()
def builder = new groovy.xml.MarkupBuilder(writer)
builder.languages {
language(year: 1995) {
name "java"
paradigm "Object oriented"
typing "Static"
}
language (year: 1995) {
name "ruby"
paradigm "Object oriented, Functional"
typing "Dynamic, Duck typing"
}
language (year: 2003) {
name "groovy"
paradigm "Object oriented, Functional"
typing "Dynamic, Static, Duck typing"
}
}
And also can be processed in a streaming way through StreamingMarkupBuilder
. To change the implementation to JSON, we can just swap the MarkupBuilder
to JsonBuilder
.[29]
To parse it and search for a functional language we can use Groovy's findAll
method:
def languages = new XmlSlurper().parseText writer.toString()
// Here we employ groovy's regex syntax for a matcher (=~) which will be coerced to a boolean value:
// either true if the value contains our string, or false otherwise.
def functional = languages.language.findAll { it.paradigm =~ "functional" }
assert functional.collect { it.name } == ["ruby", "groovy"]
String interpolation
In Groovy we can interpolate the string with variables and expressions by using GStrings:[30]
BigDecimal account = 10.0
def text = "Your account shows currently a balance of $account"
assert text == "Your account shows currently a balance of 10.0"
GStrings containing variables and expressions must be declared using double quotes.
A complex expression must be enclosed in curly brackets. This prevents parts of it from being interpreted as belonging to the surrounding string instead of to the expression:
BigDecimal minus = 4.0
text = "Your account shows currently a balance of ${account - minus}"
assert text == "Your account shows currently a balance of 6.0"
// Without the brackets to isolate the expression, we would have the following:
text = "Your account shows currently a balance of $account - minus"
assert text == "Your account shows currently a balance of 10.0 - minus"
Expression evaluation can be deferred by employing arrow syntax:
BigDecimal tax = 0.15
text = "Your account shows currently a balance of ${->account - account * tax}"
tax = 0.10
// The tax value was changed AFTER declaration of the GString. The expression
// variables are bound only when the expression must actually be evaluated:
assert text == "Your account shows currently a balance of 9.000"
AST (Abstract Syntax Tree) Transformation
According to Groovy's own documentation, "When the Groovy compiler compiles Groovy scripts and classes, at some point in the process, the source code will end up being represented in memory in the form of a Concrete Syntax Tree, then transformed into an Abstract Syntax Tree. The purpose of AST Transformations is to let developers hook into the compilation process to be able to modify the AST before it is turned into bytecode that will be run by the JVM. AST Transformations provides Groovy with improved compile-time metaprogramming capabilities allowing powerful flexibility at the language level, without a runtime performance penalty.".[31]
Examples of ASTs in Groovy are:
- Singleton transformation;
- Category and Mixin transformation;
- Immutable AST Macro;
- Newify transformation;
Among others.
Traits
According to Groovy's documentation, "Traits are a structural construct of the language which allow: composition of behaviors, runtime implementation of interfaces, behavior overriding, and compatibility with static type checking/compilation."
Traits can be seen as interfaces carrying both default implementations and state. A trait is defined using the trait keyword:
trait FlyingAbility { /* declaration of a trait */
String fly() { "I'm flying!" } /* declaration of a method inside a trait */
}
Then it can be used like a normal interface using the implements keyword:
class Bird implements FlyingAbility {} /* Adds the trait FlyingAbility to the Bird class capabilities */
def b = new Bird() /* instantiate a new Bird */
assert b.fly() == "I'm flying!" /* the Bird class automatically gets the behavior of the FlyingAbility trait */
Traits allow a wide range of capabilities, from simple composition to testing.
Adoption
- eXo Platform, an Open Source Enterprise Social Collaboration Platform uses Groovy.
- Wired.com uses Groovy and Grails for the Product Reviews standalone section of the website.[32]
- Though Groovy can be integrated into any JVM environment, the JBoss Seam framework provides Groovy, besides Java, as a development language, out of the box.[33]
- The European Patent Office (EPO) developed a Data Flow Language in Groovy "to leverage similarities in the processes for communicating with each individual country’s patent office, and transform them into a single, universal process."
- Linkedin uses Groovy and Grails for some of their subsystems.[34]
- XWiki SAS uses Groovy as scripting language in their collaborative open-source product.[35]
- SoapUI provides Groovy as a language for webservice tests development.[36]
- Sky.com uses Groovy and Grails to serve massive online media content.[37]
- DataMelt integrates Groovy into a numeric and statistic data-analysis framework
- vCalc.com uses Groovy for all of the user defined mathematics in its math crowd-sourcing engine.[38]
- Eucalyptus, a cloud management system, uses a significant amount of Groovy.
- Apache OFBiz, the open source enterprise resource planning (ERP) system, uses Groovy.[39][40]
- SmartThings, an open platform for smart homes and the consumer Internet of Things, uses a security-oriented subset of Groovy[41]
- Survata, a market research startup, uses Groovy and Grails.
- Jenkins, a platform for continuous integration. With version 2, Jenkins includes a Pipeline plugin that allows for build instructions to be written in Groovy.[42]
IDE support
Many integrated development environments and text editors support Groovy:
- Eclipse, through Groovy-Eclipse
- Emacs, using the groovy-emacs-mode project's groovy-mode.
- IntelliJ IDEA, Community Edition, Grails/Griffon in the Ultimate Edition only
- NetBeans, since version 6.5
- TextMate
- DataMelt Java IDE
- Sublime Text 2, a cross platform text editor
- JDeveloper, for use with Oracle ADF
- jEdit, an advanced text editor for the Java Platform
- Kate, an advanced text editor for KDE supports Groovy and over 200 other file formats
- Notepad++, an advanced text editor for Microsoft Windows
- Android Studio, IDE used for making Android apps
- Atom IDE
See also
- Griffon – a desktop framework
- Gradle – a build automation tool
- Project Zero
- Comparison of programming languages
References
Citations
- ↑ "Groovy 2.0 Performance compared to Java". 25 Aug 2012.
- ↑ "Java vs Groovy2.0 vs Scala Simple Performance Test". 10 Jul 2012.
- 1 2 "Groovy 2.4 And Grails 3.0 To Be Last Major Releases Under Pivotal Sponsorship". 19 Jan 2015.
- 1 2 "Groovy joins Apache Incubator". 11 Mar 2015.
- ↑ James Strachan (29 Aug 2003). "Groovy - the birth of a new dynamic language for the Java platform".
- ↑ "Groovy wins first prize at JAX 2007 innovation award". 2007-04-26.
- ↑ "They say a lot can happen over a cup of coffee".
- ↑ "SpringSource Acquires Groovy and Grails company (G2One)". 11 Nov 2008.
- ↑ "VMWare Acquires SpringSource". 10 Aug 2009.
- ↑ "Scala as the long term replacement for java/javac?". July 6, 2009. Retrieved 2009-12-29.
- ↑ "Java Community Process JSR 241".
- ↑ "Announcement on dev mailing list".
- ↑ König 2007, pg. 32
- ↑ "Groovy style and language feature guidelines for Java developers". Groovy.codehaus.org. Retrieved 2015-01-22.
- ↑ "Groovy - Differences from Java". Groovy.codehaus.org. Retrieved 2013-08-12.
- ↑ "What's new in Groovy 2.0?". 28 Jun 2012.
- ↑ König 2007, pp. 37-8
- ↑ König 2007, pp. 38-9
- ↑ König 2007, pp. 41-3
- ↑ "JN3525-MetaClasses".
- ↑ "Metaprogramming Techniques in Groovy and Grails". 11 Jun 2009.
- ↑ "Groovy - Closures".
- 1 2 "Does groovy call partial application 'currying'". 10 Aug 2013
- ↑ "Groovy - Lazy Transformation".
- ↑ "Side Notes: Lazy lists in Groovy". 3 Feb 2011.
- ↑ "Groovy's Fold". 20 Jun 2011.
- ↑ "Functional Programming with Groovy". 5 Nov 2011.
- ↑ "Function programming in Groovy".
- ↑ "JsonBuilder".
- ↑ "Groovy Strings - Different ways of creating them". 26 Dec 2009.
- ↑ "Compile-time Metaprogramming - AST Transformations".
- ↑ "Wired.Com" (PDF). www.springsource.org. Retrieved 2015-06-02.
- ↑ "Chapter 11. Groovy integration". docs.jboss.org. Retrieved 2015-06-02.
- ↑ "Grails at LinkedIn". Retrieved 2015-06-02.
- ↑ "XWiki SAS" (PDF). www.springsource.org. Retrieved 2015-06-02.
- ↑ "Scripting and the Script Library | Scripting & Properties". www.soapui.org. Retrieved 2015-06-02.
- ↑ Rocher, Graeme (October 2, 2008). "Graeme Rocher's Blog: Sky.com relaunches written in Grails". Graeme Rocher's Blog. Retrieved 2015-06-02.
- ↑ "vCalc, the First ever Social Platform for the world of Math". Retrieved 2016-05-05.
- ↑ "Groovy DSL for OFBiz business logic". Apache OFBiz Project Open Wiki.
- ↑ "Simple-methods examples using Groovy". Apache OFBiz Project Open Wiki.
- ↑ Security Analysis of Emerging Smart Home Applications
- ↑ "Jenkins Pipeline".
Sources
- König, Dierk; Paul King; Guillaume Laforge; Hamlet D'Arcy; Cédric Champeau; Erik Pragt; Jon Skeet (2015). Groovy in Action, Second Edition. Manning. ISBN 978-1-935182-44-3.
- Barclay, Kenneth; John Savage. Groovy Programming: An Introduction for Java Developers. ISBN 978-0-12-372507-3.
- Davis, Scott. Groovy Recipes: Greasing the Wheels of Java. ISBN 978-0-9787392-9-4.
- Subramaniam, Venkat. Programming Groovy: Dynamic Productivity for the Java Developer. ISBN 978-1-934356-09-8.